[ntp:questions] bad time with a laptop on windows 7

Brian Inglis Brian.Inglis at SystematicSw.ab.ca
Thu Sep 4 02:15:16 UTC 2014


On 2014-08-01 15:33, Greg Hennessy wrote:
> I upgraded to the 4.2.7 via
> http://www.satsignal.eu/ntp/x86/ntp-4.2.7p454-win-x86-bin-djt.zip
> and I get much better performance, as seen:
> https://docs.google.com/file/d/0B7E_xYSeZSYqLTd1NnprQjlNZW8/edit
> A plot of one hours worth of data looks like
> https://docs.google.com/file/d/0B7E_xYSeZSYqT1c5bW9tWFlnQ2s/edit

Set your laptop power profile to High performance - see previous post on July 24.

Would be nice to see all the details.
Try the following as you seem to be using gnuplot:

# loopstats.gp

# functions

MJDtoS(MJD,s)=((MJD-40587.)*86400.+s)

# settings

set tics out
set timefmt '%s'	# input time in Unix seconds
set xdata time
set autoscale x
set format x '%R'	# output strftime HH:MM
set xlabel 'UTC (hh:mm)'
set autoscale y
set format y '%.0s%cs'	# gnuplot scientific format e.g. 10us
set logscale y		# log y scale
set ylabel 'Offset/Jitter'
set ytics nomirror	# allow y2 axis
set y2tics
set my2tics 5		# force minor y2 tics
set autoscale y2
set y2label 'Drift/Wander (ppm)'
set title L		# input filename is title
set style data lines
set bars small
set pointsize 0.1
set boxwidth 0.1
set key under reverse Left samplen 1
set terminal png font 'ArialNarrow,10' size 1920,1080 background 'grey90'
set output P		# PNG most compact output

# plot

plot L using (MJDtoS($1,$2)):(abs($3)):($3<0?1:2) lc variable \
						title 'Offset' axes x1y1 \
,   '' using (MJDtoS($1,$2)):5 ls 3 \
						title 'Jitter' axes x1y1 \
,   '' using (MJDtoS($1,$2)):4:6 with yerrorlines ls 4 \
						title 'Drift/Wander' axes x1y2

Filenames L (loopstats input) and P (PNG output) should be passed as
command line parameters e.g.
gnuplot -e 'L="loopstats.20140802"' -e 'P="loopstats.20140802.png"' loopstats.gp

-- 
Take care. Thanks, Brian Inglis

_______________________________________________
questions mailing list
questions at lists.ntp.org
http://lists.ntp.org/listinfo/questions



More information about the questions mailing list